;cosydfhstp.dmo
;Avance version
;
;2D homonuclear shift correlation
;phase sensitive using TPPI
;with double qunatum filter via BSMS homospoil pulse
;with spoil pulses to suppress rapid scanning artifacts
;
;setup the homospoil pulses:
;     sequence = 12
;     intensity pulse 1 = 30000, pulse 2 = -60000
;     fine adjustment of pulse 2 in the GS-mode:
;            minimize singulets, maximize coupled protons

#include <Avance.incl>

"d0=3u"
"d11=30m"
"d12=20u"
"d13=3u"
"d27=p16+150u"
"p10=10m"
"p11=20m"

1 ze
2 d11
3 d12 pl10:f1         ;pl10=pl1+12dB
  d13
  (p10 ph10 3u p11 ph11):f1   ;spoil pulses
  d13
  d1 pl1:f1
  p1 ph1
  d0
  d20
  p1 ph2
  d13 LOCKH_ON
       3u HS_ON
       d27
       3u HS_OFF
       d16

 p1 ph3
 d13
       3u HS_ON
       d27
       3u HS_OFF
       d16
 d20 LOCKH_OFF
 go=2 ph31
 d11 wr #0 if #0 id0 ip1 zd
 lo to 3 times td1
exit

ph1=0 2
ph2=0
ph3=0
ph10=0
ph11=1
ph31=0 2

;ND0=2
;p16 = 2ms
;d16=5ms
;d20=35ms (to enhance double quantum)
;ns = 2
;shape = sine
;sequence = 12
;compensation: not used
;pulse amplitude after fine adjustment:
;         pulse 1 : 30000
;         pulse 2: -51214
;