;noesygptp.val
;2D homonuclear correlation via dipolar coupling 
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive using TPPI
;with gradient pulse in mixing time
;R. Wagner & S. Berger, J. Magn. Reson. 123 A, 119-121 (1996)
;
; val mar 4,'98
; http://nmr.ioc.ac.ru/Staff/AnanikovVP/
;
#include <Avance.incl>
#include <Grad.incl>


"d0=3u"
"p16=d8"


1 ze
2 d1
3 p1 ph1
  d0
  p1 ph2
  50u UNBLKGRAD
  p16:gp1
  d16
  4u BLKGRAD
  p1 ph3
  go=2 ph31
  d1 wr #0 if #0 id0 ip1 zd
  lo to 3 times td1
exit


ph1=0 2 
ph2=0
ph3=0
ph31=0 2


;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse  = mixing time 
;d8 : mixing time
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d16: delay for homospoil/gradient recovery
;in0: 1/(2 * SW) = DW
;nd0: 2
;NS: 2 * n
;DS: 16
;td1: number of experiments
;MC2:  TPPI
;use gradient  gp 1 : 0.01T/m = 1G/cm; 1-2%